<!--#include file="config.asp"-->

<%
Dim Rs,SQL,foundstr
Dim classid,ChildStr
Dim RssBody,RssTitle,RssHomePageUrl
Dim XMLDOM,node,Cnode,Cnode1,msginfo
Dim ChannelsetArray,xmlFilePath,m_xmlFilePath,m_strXmlPath,TextContent,isxmltext,xmlfilename

Set XMLDOM = Server.CreateObject("Microsoft.FreeThreadedXMLDOM")
XMLDOM.appendChild(XMLDOM.createElement("rss"))
XMLDOM.documentElement.attributes.setNamedItem(XMLDOM.createNode(2,"version","")).text="2.0"
Set node = XMLDOM.documentElement.appendChild(XMLDOM.createNode(1,"channel",""))
node.appendChild(XMLDOM.createTextNode(vbCrLf))
RssTitle = "获取文章列表"
classid = Newasp.CheckNumeric(Request("classid"))

Dim ChannelRootDir,m_strInstallPath
If Newasp.BindDomain = "0" Then
	ChannelRootDir = Newasp.SiteUrl & Newasp.InstallDir & Newasp.ChannelDir
	RssHomePageUrl = Newasp.SiteUrl
	m_strInstallPath = Newasp.InstallDir & Newasp.ChannelDir
Else
	ChannelRootDir = Newasp.DomainName & "/"
	RssHomePageUrl = Newasp.DomainName
	m_strInstallPath = "/"
End If

ChannelsetArray = Split(Newasp.Channel_Setting & "|||||||||||||||", "|||")
m_xmlFilePath = Trim(ChannelsetArray(12))
If Len(m_xmlFilePath) > 2 And InStr(m_xmlFilePath, ":") > 0 Then
	m_strXmlPath = m_xmlFilePath &"\"
Else
	m_strXmlPath = Server.MapPath(m_strInstallPath & m_xmlFilePath) & "\"
End If
m_strXmlPath = Replace(m_strXmlPath, "\\", "\")

Sub XMLArticleList()
	Dim specialID,stype
	If Trim(Request("specialID")) <> "" Then
		specialID = Newasp.CheckNumeric(Request("SpecialID"))
		specialID = CLng(specialID)
		If specialID = 0 Then
			foundstr = "And A.specialID>0 ORDER BY A.WriteTime DESC ,A.ArticleID DESC"
		Else
			foundstr = "And A.specialID=" & specialID & " ORDER BY A.WriteTime DESC ,A.ArticleID DESC"
		End If
	Else
		If classid > 0 Then
			SQL = "SELECT ClassName,ChildStr FROM [NC_Classify] WHERE ChannelID = " & ChannelID & " And ClassID=" & CLng(classid)
			Set Rs = Newasp.Execute(SQL)
			If Rs.BOF And Rs.EOF Then
				Set Cnode=node.appendChild(XMLDOM.createNode(1,"item",""))
				Cnode.appendChild(XMLDOM.createNode(1,"title","")).text="没有找到文章分类"
				Cnode.appendChild(XMLDOM.createNode(1,"link","")).text=RssHomePageUrl
				Cnode.appendChild(XMLDOM.createNode(1,"author","")).text=Newasp.SiteName
				Cnode.appendChild(XMLDOM.createNode(1,"pubDate","")).text=Newasp.FormatDate(Now(),1)
				Set Cnode1=Cnode.appendChild(XMLDOM.createNode(1,"description",""))
				msginfo= "没有找到文章分类！"
				Cnode1.appendChild(XMLDOM.createCDATASection(msginfo))
				Cnode.appendChild(XMLDOM.createNode(1,"category","")).text=" "
				Rs.Close: Set Rs = Nothing
				Exit Sub
			Else
				RssTitle = Rs("ClassName")
				ChildStr = Rs("ChildStr")
			End If
			Rs.Close:Set Rs = Nothing
			foundstr = "And A.ClassID in (" & ChildStr & ") ORDER BY A.WriteTime DESC ,A.ArticleID DESC"
		Else
			RssTitle = "全部文章列表"
			foundstr = "ORDER BY A.WriteTime DESC ,A.ArticleID DESC"
		End If
	End If
	If Trim(Request("type")) <> "" Then
		stype = Newasp.CheckNumeric(Request("type"))
		stype = CInt(stype)
		If stype = 0 Then
			foundstr = Replace(foundstr, "A.WriteTime", "A.AllHits")
		Else
			foundstr = "And IsBest>0 " & foundstr
		End If
	End If
	node.appendChild(XMLDOM.createNode(1,"title","")).text=RssTitle & " - " & Newasp.SiteName
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"link","")).text=Newasp.SiteUrl
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"language","")).text="zh-cn"
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"description","")).text=Newasp.SiteName
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"copyright","")).text=Newasp.SiteUrl
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"generator","")).text="Rss Generator By Newasp.Net"
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	node.appendChild(XMLDOM.createNode(1,"docs","")).text=RssHomePageUrl & Request.ServerVariables("PATH_INFO")
	node.appendChild(XMLDOM.createTextNode(vbCrLf))
	Set Cnode=node.appendChild(XMLDOM.createNode(1,"image",""))
	Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
	Cnode.appendChild(XMLDOM.createNode(1,"title","")).appendChild(XMLDOM.createCDATASection(Replace(Trim(Newasp.SiteName), "&nbsp;", "")))
	Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
	Cnode.appendChild(XMLDOM.createNode(1,"url","")).text=Newasp.SiteUrl & "/images/logo.gif"
	Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
	Cnode.appendChild(XMLDOM.createNode(1,"link","")).text=Newasp.SiteUrl
	Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))

	Dim HtmlFileName,HtmlFileUrl
	SQL = " A.ArticleID,A.ClassID,A.title,A.Content,A.WriteTime,A.HtmlFileDate,A.author,A.isxmltext,A.xmlfilename,"
	SQL = "SELECT top 100 " & SQL & " C.ClassName,C.HtmlFileDir,C.UseHtml,B.ChannelDir,B.StopChannel,B.ModuleName,B.IsCreateHtml,B.HtmlExtName FROM ([NC_Article] A INNER JOIN [NC_Classify] C On A.ClassID=C.ClassID) INNER JOIN [NC_Channel] B On A.ChannelID=B.ChannelID WHERE A.isAccept>0 And A.ChannelID=" & CLng(ChannelID) & " " & foundstr & ""
	Set Rs = Newasp.Execute(SQL)
	If Rs.BOF And Rs.EOF Then
		Set Cnode=node.appendChild(XMLDOM.createNode(1,"item",""))
		Cnode.appendChild(XMLDOM.createNode(1,"title","")).text="没有找到文章"
		Cnode.appendChild(XMLDOM.createNode(1,"link","")).text=RssHomePageUrl
		Cnode.appendChild(XMLDOM.createNode(1,"author","")).text=Newasp.SiteName
		Cnode.appendChild(XMLDOM.createNode(1,"pubDate","")).text=Newasp.FormatDate(Now(),1)
		Set Cnode1=Cnode.appendChild(XMLDOM.createNode(1,"description",""))
		msginfo= "没有找到文章！"
		Cnode1.appendChild(XMLDOM.createCDATASection(msginfo))
		Cnode.appendChild(XMLDOM.createNode(1,"category","")).text=" "
		Rs.Close: Set Rs = Nothing
		Exit Sub
	Else
		Do While Not Rs.EOF
			If Rs("IsCreateHtml") <> 0 Then
				HtmlFileUrl = RssHomePageUrl & Newasp.ReadDestination(Newasp.InfoDestination, Newasp.ChannelDir, Rs("HtmlFileDate"),Rs("HtmlFileDir"),Rs("ClassID"),Rs("ArticleID"),1,"")
			Else
				If IsURLRewrite Then
					HtmlFileUrl = ChannelRootDir & Rs("ArticleID") & Newasp.HtmlExtName
				Else
					HtmlFileUrl = ChannelRootDir & "show.asp?id=" & Rs("ArticleID")
				End If
			End If
			'--如果是XML文件,就从XML文件中读出内容------
			isxmltext = Newasp.ChkNumeric(Rs("isxmltext"))
			xmlfilename = Rs("xmlfilename") & ""
			If isxmltext = 1 Then
				xmlFilePath = m_strXmlPath & xmlfilename
				TextContent = Newasp.ReadXMLDocument(xmlFilePath,"article/@content")
				If TextContent = "" Then TextContent = Rs("content") & ""
			Else
				TextContent = Rs("content")
			End If
			'---------------------------------------------
			node.appendChild(XMLDOM.createTextNode(vbCrLf))
			Set Cnode=node.appendChild(XMLDOM.createNode(1,"item",""))
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"title","")).appendChild(XMLDOM.createCDATASection(Replace(Trim(Rs("title")), "&nbsp;", "")))
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"link","")).text=HtmlFileUrl
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"category","")).text=Rs("ClassName")
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"author","")).text=Rs("author")
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"category","")).appendChild(XMLDOM.createCDATASection(Rs("ClassName")))
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Cnode.appendChild(XMLDOM.createNode(1,"pubDate","")).text=Newasp.FormatDate(Rs("WriteTime"),1)
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Set Cnode1=Cnode.appendChild(XMLDOM.createNode(1,"description",""))
			msginfo=  Newasp.CutString(TextContent, 300)
			Cnode1.appendChild(XMLDOM.createCDATASection(msginfo))
			Cnode.appendChild(XMLDOM.createTextNode(vbCrLf))
			Rs.MoveNext
		Loop
	End If
	Rs.Close: Set Rs = Nothing
End Sub

Sub ShowXML()
	Response.Clear
	Response.CharSet="gb2312"
	Response.ContentType="text/xml"
	Response.Write "<?xml version=""1.0"" encoding=""gb2312""?>" & vbCrLf
	Response.Write XMLDOM.xml & vbCrLf
	Set XMLDOM=Nothing
End Sub


XMLArticleList()
ShowXML()
CloseConn



%>